Friday, March 3, 2017

Monkey-X - Beginners - Vector Rotation Helper - code example


Import mojo

' This is the vector class. It has a 
' x and y float variable.
'
Class vectorf
    Field x:Float,y:Float
    Method New(x:Float = 0,y:Float = 0)
        Self.x = x
        Self.y = y
    End Method
End Class

Class MyGame Extends App
    ' Here we create a 'a' variable using the
    ' vectorf class
    Field a:vectorf
    '
    '
    Field angle:Float
    ' cx and cy contain the center x and center y
    ' coordinates of the screen.
    Field cx:Int
    Field cy:Int
    ' time is a variable used to change(refresh)
    ' the information on the screen.
    Field time:Int
    Method OnCreate()
        SetUpdateRate(60)
        Seed = GetDate[4] + GetDate[5]
        cx = DeviceWidth()/2
        cy = DeviceHeight()/2
        ' Here we create a new vector in
        ' a with a new value(x and y)
        a = New vectorf(Rnd(-10,10),Rnd(10,10))
    End Method
    Method OnUpdate()
        '
        '
        angle+=3
        If angle>359 Then angle=0
        '                 
        time+=1
        If time>300 Then
            time=0
            a = New vectorf(Rnd(-10,10),Rnd(-10,10))
        End If
    End Method
    Method OnRender()
        ' pointx and y hold the coordinates
        ' that are used to draw on the screen.
        Local pointx:Int
        Local pointy:Int
        Cls 0,0,0 
        SetColor 255,255,255
        ' Here we draw the helper screen part.
        DrawLine cx,0,cx,DeviceHeight
        DrawLine 0,cy,DeviceWidth,cy
         DrawText "-X",0,cy
         DrawText "+X",DeviceWidth()-30,cy
         DrawText "-Y",cx,0
         DrawText "+Y",cx,DeviceHeight()-30
         DrawText "0,0",cx,cy,.5,.5
         DrawText "Origin",cx+5,cy-20
        '
        ' Here we draw the vector a.
        SetColor 255,255,255
        pointx = (a.x*13) + cx
        pointy = (a.y*13) + cy
        DrawCircle pointx,pointy,7
        DrawLine cx,cy,pointx,pointy
        DrawText "a",pointx,pointy,.5,.5
        DrawText String(a.x)[0..4]+","+String(a.y)[0..4],pointx+5,pointy+10,.5,.5
        '
        ' Here we draw the rotated vector (b)
        SetColor 255,255,0
        Local b:vectorf = New vectorf()
        b = rotate_vector(a,angle)
        pointx = (b.x*13) + cx
        pointy = (b.y*13) + cy 
        DrawCircle pointx,pointy,7
           DrawLine cx,cy,pointx,pointy
        DrawText "b",pointx,pointy,.5,.5
         
        '        
        ' Here we draw the Screen info
        SetColor 255,255,255
        Scale 1.2,1.2
        SetAlpha 1
        '
        ' String(mystring)[0..4] creates a string with 4 
        ' characters. [ 0,1,2,3 ] Left to right.
        '
        DrawText "Vector Rotation Degrees : "+angle,0,0
        DrawText "Vector rotation changes the direction in which",0,20
        DrawText "a vector points. The vector length stays the same.",0,40
        SetAlpha 0.6
        DrawText "Vector Rotation :",cx-30,DeviceHeight-160
        DrawText "b.x = v.x * Cos(degrees) - v.y * Sin(degrees)",cx-100,DeviceHeight-140
        DrawText "r.y = v.x * Sin(degrees) + v.y * Cos(degrees)",cx-100,DeviceHeight-120

    End Method
End Class

'
' Here is the function that rotates a vector. It returns the
' new rotated vector.
'
Function rotate_vector:vectorf(v:vectorf,degrees:Float)
    Local r:vectorf = New vectorf()
    r.x = v.x * Cos(degrees) - v.y * Sin(degrees)
    r.y = v.x * Sin(degrees) + v.y * Cos(degrees)
    Return r
End Function

Function Main()
    New MyGame()
End Function

No comments:

Post a Comment

Note: Only a member of this blog may post a comment.